muscript <<EOT
# demonstrates use of muscript variables to generate an alberti bass
3 systems 120/19-25-19/19-25-19/19-25-19 120/
midi channel 0 patch 0 pan 80
midi channel 1 patch 0 pan 20
$CMAJ={
	$S1=e~
	$S2=c~
	$S3=g
}
$DMAJ={
	$S1=d~
	$S2=a
	$S3=f
}
$GMAJ={
	$S1=d~
	$S2=b
	$S3=g
}
$ALBERTI= [$S3 $S1 $S2 $S1]
$LHBAR= =2 16 $ALBERTI $ALBERTI $ALBERTI $ALBERTI
/
3 bars | 16 |
| 2.0
=1  treble 1# cha0 leg100 vol95 2 rest 8 rest [d-. g-. d-.]
=2  bass   1# cha1 leg160 vol80 2 blank 1 rest
|
$CMAJ
=1 8 [d#-emph e-.] 4. e 16 [e f] [a g f e]
$LHBAR
|
$GMAJ
=1 8 [e-emph d-.] 4. d 16 [B c] [e d c B]
$LHBAR
|
$DMAJ
=1 16 [A G A B'] 8 [c-. e-.] [d{1 c}1 B-. A,-.]
$LHBAR
|
$GMAJ
=1 8 [A#-ten B'] 4. B' 8 [d-. g-. d-.]
$LHBAR
|
$CMAJ
=1 8 [d#-ten e-.] 4. e 16 [e f] [a g f e]
$LHBAR
|
$GMAJ
=1 8 [e-ten d-.] 4. d 16 [B c] [e d c B]
$LHBAR
| 1.0 1.1
$DMAJ
=1 16 [A G A B'] 8 [c-. e-.] vol+10 [d-. B-. c-. A,-.]
=2, 16 $ALBERTI $ALBERTI \
 8 leg65 vol90 [<f-., a d~> <g-., b d~> <e-., g c~> <d f d~>]
|
$GMAJ
=1 2 G-emph rest
=2, 2 leg100 <g b d~> rest